问题: 我周围的人都搞不懂,在DELPHI中怎样运行字符中所包含的命令 ( 积分: 100 )
分类: 非技术问题
来自: s9461128946112894611, 时间: 2003-08-27 9:40:00, ID: 2136479
在DELPHI中怎样运行字符中所包含的命令
有如下代码
procedure .......
var
s:string;
begin
s:="form1.button1.enabled:=true"；
怎样通过运行S来达到给form1.button1.enabled赋值true
及运行
aaaa s
就可以达到
给form1.button1.enabled赋值true
请问有aaaa这个命令吗？
来自: 来如风, 时间: 2003-08-27 9:46:00, ID: 2136495
没有
来自: ycxy, 时间: 2003-08-27 9:47:00, ID: 2136496
这是不可能的
你只能通过程序来判断执行
如
case i of
1:form1.button1.enabled:=true;
2:..
end;
来自: HunterTeam, 时间: 2003-08-27 9:48:00, ID: 2136501
类似于foxpro中的&命令是吧？Delphi中没有这个命令，只能对字符串进行解析判断后才能
作具体的处理。
来自: linglingx, 时间: 2003-08-27 9:51:00, ID: 2136513
你自己做一个像Delphi的编译器也就可以执行了，呵呵～
来自: superFans, 时间: 2003-08-27 9:58:00, ID: 2136541
Dream Script 控件即可 可以从51Delphi 下载，有Demo
来自: s9461128946112894611, 时间: 2003-08-28 11:54:00, ID: 2139460
怎么没有一个人回答我的问题，太难了吗？
来自: Passion, 时间: 2003-08-28 12:01:00, ID: 2139480
上面不是有这么多人回答了吗？
来自: lichaogang, 时间: 2003-08-28 12:05:00, ID: 2139488
delphi 中没有宏，你不可以这样做。
来自: 孤灯夜影, 时间: 2003-08-28 12:15:00, ID: 2139512
只能对字符串进行判断 才能执行什么
如果直接执行字符串 不太可能 除非你自己定义一个过程 也是先判断 再执行
来自: ty123, 时间: 2003-08-28 13:38:00, ID: 2139707
同意ycxy和孤灯夜影
来自: yue_shan, 时间: 2003-08-28 13:53:00, ID: 2139752
哥们，若有你这样的功能，哪写程序岂不是很舒服，从文本文件中读要执行的指令，程序编译后，这个文本文件用户都可能写，那太爽了吧，而你这个程序也相当于一个编译器了
来自: lz999, 时间: 2003-08-28 14:29:00, ID: 2139869
我今天也遇见类似的问题，需要在运行时可改变计算公式，基本包括 + - * / 等综合运算。 我想应该有办法的，因为我看到过有一个小软件能实现，如果有办法的话，能否也告知我一下？
来自: yangh888, 时间: 2003-08-28 14:43:00, ID: 2139932
关注～！
up～！
来自: clever_boy_2000, 时间: 2003-08-28 17:12:00, ID: 2140418
不可能，字符串没没经过编译
来自: 牛车, 时间: 2003-08-28 17:32:00, ID: 2140489
问题很具有挑战性。如果你的要执行的命令是少量的话应该是有办法的；如果是大量的话，嘿嘿，自己搞个编译器。
来自: Pau1, 时间: 2003-08-28 17:38:00, ID: 2140520
如何根据字符串（如：‘ABC’）判断是否存在同名的Procedure或function(如
rocedure ABC或function ABC),如存在,请教如何通过字符串(如:'ABC')调用该Procedure或function?
这在FOXPRO下很容易实现,但在DELPHI下却很棘手,不是吗?
如：
type
TProcedureType=Procedure(Num:Integer);
...
procedure ABC(Num:Integer);
procedure ProcessOtherProcedure(OtherProcedure:TProcedureType);
var
String1:string='ABC';
implementation
Procedure ABC(Num:Integer);
begin
//
//
end;
Procedure ProcessOtherProcedure(OtherProcedure:TProcedureType)
begin
OtherProcedure();
end;
请教如果不知道Procedure ABC是否存在,如何根据字符串String1的值判断是它否存在,如存在,请教如何利用字符串String1调用ProcessOtherProcedure?
-----------------------------------------------------------------------
第一篇：按名字调用方法高级解决方案。
声明：本文乃 beta 原创，如要转载请保持文章完整。
按名字调用方法高级解决方案 --- by beta
按名字调用方法似乎一直以来都是大家比较关注的技术，在论坛上有一个经典的答复：
type
TProcedure = procedure(Test: string) of object;
procedure ExecuteRoutine(Obj: TObject; Name, Param: string);
var
PMethod: TMethod;
AProcedure: TProcedure;
begin
PMethod.Data := Pointer(Obj);
PMethod.Code := Obj.MethodAddress(Name);
if Assigned(PMethod.Code) then
begin
AProcedure := TProcedure(PMethod);
AProcedure(Param);
end;
end;
使用：待调用方法声明为某个类的 published 方法，Obj 为拥有待调用方法的类的
实例，Name 和 Param 分别为待调用方法的名字和参数。
但是这个办法有一个很大的局限性：一旦 TProcedure 声明定了下来，待调用方法的参
数表也就一定了。要是我定义了多个待调用方法，且参数个数、类型、返回值均不同，
则这个办法也就无能为力了。另：用 GetProcAddress 代替 MethodAddress 也可以实
现类似的效果，不过我们今天讨论的是调用类的“方法”，而它所返回的不是“方法”，
因为 GetProcAddress 仅能取得应用程序的输出（exports）了的过程或函数，这些过
程或函数不属于任何类，也就称不上“方法”。当然，效果类似，但是局限也类似 :-(
那么要是参数的个数、类型均可变就无法解决了吗？（要是这样就不会有本文了）通过
研究，我发现了一种行之有效的办法：Format 函数（注意，不是 DOS 命令，呵呵）相
信大家都不陌生吧，传入它的参数的个数和类型不都是可变的吗？只要声明如下：
procedure AProc(Param: array of const);
即可这样调用：
AProc([123, 'X', True, 'hello'...]);
有朋友可能要说了，那不就简单了，这样不就可以了：
type
TProcedure = procedure(Params: array of const) of object;
procedure ExecuteRoutine(Obj: TObject; Name: string; Params: array of const);
var
...
begin
...
AProcedure(Params);
...
end;
别急，问题才刚刚出现呢，你运行试一试？出问题了吧。（为方便起见，暂时称我们的
ExecuteRoutine 函数，为控制函数；待调用方法简称为待调方法）这个形参表的声明
办法的确适合我们的控制函数，但是不适合待调方法。为什么？因为待调方法的形参表
的确不是这样（array of const）的啊。当然了，你说你把所有待调方法的形参表都改
成这个样子不就可以了？且不说你需要改动多少东西（包括待调函数的参数表和内部实
现，关键是内部实现部分），就看看你改了过后的待调方法的形参表，全部都成了一个
模样。说不定到时候你自己都不知道到底应该传什么参数进去了。因此，我们应该尽量
保持待调方法的形参表。
现在问题转化为了在控制函数中已知待调方法的地址及其参数列表（存放在一个
TVarRec 的数组中），如何在调用它的时候将参数传进去。这需要几点预备知识：
1. 首先我们来看看传进来的这个参数表：Params。它的类型被 Delphi 称作可变开
放数组（Variant open array），等价于 array of TVarRec，也就是说 Params 是一
个成员为 TVarRec 的数组。换句话说，在参数被传进 Params 的时候，各种类型都被
Delphi 自动转化为了 TVarRec（参见帮助中的 Variant open array parameters 一
节）。看一下 TVarRec 的定义可知，它实际储存的数据域为 4 Bytes，超过 4 Bytes
的只存指针，需要注意的是 TVarRec 的大小是 8 Bytes（经研究发现前 4 Bytes 存放
数据，第 5 Byte 为类型）。
2. 调用函数时的参数传递的一般情况（未使用 stdcall 的情况）。对于一般的函数
或过程，前三个参数分别放在 EAX、EDX、ECX，后面如果还有更多参数的话，就在堆栈
里面；对于类的方法，EAX 固定用于存放类实例的地址，EDX、ECX 分别存放前两个参
数，其余参数进栈。在堆栈中每个元素占用 4 Bytes，而前面说了，TVarRec 中储存的
数据也是 4 Bytes，刚好一个参数在堆栈里面占一个位子，处理方便。另外，结果返回
到 EAX 中。
3. 对于调用类的方法，其实有一个默认的隐藏参数 Self 作为第一个参数传入，放
入 EAX 寄存器。因此我们看到的第一参数其实是第二个，因此我们处理的时候要注意。
4. 用 ObjectPascal 语法调用方法，Delphi 会自动帮我们处理参数的传递问题，而
在汇编里面调用任何函数之前都需要先手动设置各参数。
因此，我决定用内嵌汇编的办法来解决参数传递问题：如果是一个参数，放入 EDX；若
为两个参数，分别放入 EDX，ECX；对多于两个参数的情况，用 参数个数 - 2 个循环依
次将后续参数进栈。然后将拥有待调方法的实例地址传入 EAX，就可以 CALL 了。
function ExecuteRoutine(AObj: TObject; AName: string;
Params: array of const): DWord;
const
RecSize = SizeOf(TVarRec); // 循环处理参数列表时递增的字节数
var
PFunc: Pointer;
ParCount: DWord;
begin
if not Assigned(AObj) then
raise Exception.Create ('你确定传进来的是一个对象？');
PFunc := AObj.MethodAddress(AName); // 获取方法地址
if not Assigned(PFunc) then
raise Exception.CreateFmt('找不到 %s 的 Method: %s', [AObj.ClassName,
AName]);
ParCount := High(Params) + 1; // 获取参数个数
asm
PUSH ESI // 保存 ESI，我们待会儿要用到它
MOV ESI, Params // ESI 指向参数表首址
CMP ParCount, 1 // 判断参数个数
JB @NoParam
JE @OneParam
CMP ParCount, 2
JE @TwoParams
@ManyParams: // 超过两个参数
CLD // 清空方向标志
MOV ECX, ParCount
SUB ECX, 2 // 循环 ParCount - 2 次
MOV EDX, RecSize // EDX 依次指向每个参数的首址，每次递增 8 Bytes
ADD EDX, RecSize // 跳过前两个参数
@ParamLoop:
MOV EAX, [ESI][EDX] // 用基址变址寻址方式取得一个参数
PUSH EAX // 参数进栈
ADD EDX, RecSize // EDX 指向下一个参数首址
LOOP @ParamLoop
@TwoParams: // 两个参数
MOV ECX, [ESI] + RecSize
@OneParam: // 一个参数
MOV EDX, [ESI]
@NoParam:
MOV EAX, AObj // 传入实例地址（即，隐藏参数 Self）
CALL PFunc // 调用方法
MOV Result, EAX // 返回值放入 Result
POP ESI // 记得还原
end;
end;
前面已经说过了，任何类型都可以塞进 4 Bytes，因此将返回值定义为 DWord，你可以
根据自己的需要进行类型转换。这个办法最大限度地保护了待调方法，但也不是完全不
用修改，只有一个地方需要作出适当调整：与 DLL 中的函数返回值一样（别告诉我引用
ShareMem，那不属于本文讨论的范畴），如果要返回一个长 string，请改为 PChar，
并注意申请必要的空间。
以下是一个使用的例子（再次提醒一下，待调方法必须是某个类的 published 方法）：
TForm1 = class(TForm)
Button1: TButton;
procedure Button1Click(Sender: TObject);
private
{ Private declarations }
public
{ Public declarations }
published // 几个待调方法
function TowInt(I, J: Integer): Integer;
function ThreeInt(I, J, K: Integer): Integer;
function FiveInt(X1, X2, X3, X4, X5: Integer): Integer;
function ThreeChar(I, J, K: Char): PChar;
function TwoStr(X, Y: string): PChar;
function IntNBool(I: Integer; B: Boolean): Boolean;
end;
...
function ExecuteRoutine(AObj: TObject; AName: string;
Params: array of const): DWord;
...
function TForm1.TowInt(I, J: Integer): Integer;
begin
ShowMessage(Format('%d + %d', [I, J]));
Result := I + J;
end;
function TForm1.ThreeInt(I, J, K: Integer): Integer;
begin
ShowMessage(Format('%d + %d + %d', [I, J, K]));
Result := I + J + K;
end;
function TForm1.FiveInt(X1, X2, X3, X4, X5: Integer): Integer;
begin
ShowMessage(Format('%d + %d + %d + %d + %d', [X1, X2, X3, X4, X5]));
Result := X1 + X2 + X3 + X4 + X5;
end;
function TForm1.ThreeChar(I, J, K: Char): PChar;
var
Res: string;
begin
ShowMessage(Format('%s + %s + %s', [I, J, K]));
Res := I + J + K;
Result := AllocMem(Length(Res) + 1);
StrPCopy(Result, Res);
end;
function TForm1.TwoStr(X, Y: string): PChar;
var
Res: string;
begin
ShowMessage(Format('%s + %s', [X, Y]));
Res := X + Y;
Result := AllocMem(Length(Res) + 1);
StrPCopy(Result, Res);
end;
function TForm1.IntNBool(I: Integer; B: Boolean): Boolean;
begin
if B then
ShowMessage(IntToStr(I) + ' and True')
else
ShowMessage(IntToStr(I) + ' and False');
Result := B;
end;
procedure TForm1.Button1Click(Sender: TObject);
var
i: Integer;
b: Boolean;
s: string;
begin
i := ExecuteRoutine(Self, 'ThreeInt', [10, 23, 17]);
ShowMessage('Result: ' + IntToStr(i));
i := ExecuteRoutine(Self, 'FiveInt', [1, 2, 3, 4, 5]);
ShowMessage('Result: ' + IntToStr(i));
b := Boolean(ExecuteRoutine(Self, 'IntNBool', [10, False]));
if b then
ShowMessage('Result: True')
else
ShowMessage('Result: False');
s := PChar(ExecuteRoutine(Self, 'ThreeChar', ['a', 'b', 'c']));
ShowMessage('Result: ' + s);
s := PChar(ExecuteRoutine(Self, 'TwoStr', ['hello', ' world']));
ShowMessage('Result: ' + s);
end;
...
我之所以称该办法为高级解决方案，而非终极，因为它仍然有一个问题没有解决：变参
问题。但是这不是什么大问题，因为完全可以用函数返回值代替变参。啊？你要返回多
个值？那建议返回一个指向结构体的指针，或一个最简单的对象。
来自: fisheryj, 时间: 2003-08-28 17:42:00, ID: 2140529
太麻烦了
还是用 IF THEN
ELSE
吧
问题讨论没有结束 ...
