如何在DEPHI中控制WORD的文档写入？ ( 积分: 100 )

我在DEPHI中用wordapplication和worddocument来实现word文档的写入。现在有一个问题：我想把最后两行文字放在文档的最后一页的最底下（也就是说，无论前面有多少页多少行，通过加空格行的方法，要保证最后的两行文字在最后一页的最后两行。）。这中间就要有办法实现对我前面内容行数的计算，或能控制我当前插入的文字在当前页的行数位置。请高手指教。

我在DEPHI中用wordapplication和worddocument来实现word文档的写入。现在有一个问题：我想把最后两行文字放在文档的最后一页的最底下（也就是说，无论前面有多少页多少行，通过加空格行的方法，要保证最后的两行文字在最后一页的最后两行。）。这中间就要有办法实现对我前面内容行数的计算，或能控制我当前插入的文字在当前页的行数位置。请高手指教。

用range

看看这个有没有用？？？
再谈Delphi 7控制Word 2000——使用模板 选择自 neowang 的 Blog
关键字 再谈Delphi 7控制Word 2000——使用模板
出处

我首先想说明的是这篇文章算是我以前写的“使用Delphi 7控制Word 2000生成文档的方法”http://blog.csdn.net/neowang/archive/2004/10/08/127522.aspx的续篇（到目前为止，该文章已经被浏览了214＋11次）。
因为用户的需求发生了改变，我不得不在复习备考自然辩证法的几天里挤出时间来改写源程序来满足新的需求（看在是老同学的面子上，另一方面也不想占用自己过圣诞节的宝贵时间）。
原来的值班日志是直接一行接一行的输出到一个空白文档中的（也可以看做是输出到以Normal.dot为模板创建的新文档中），这次老同学给我发来了一个他用Word画的表格，要求程序的输出要插入到表格对应的空白处。这个表格并不是一个规整的m×n的表格，而是经过合并单元格处理的，这样就提高了难度。
我本来是打算操纵VBA中的对象来画出一个相同的表格的，可是试过以后才发现这个方法十分复杂，工作量较大，就中途放弃了。这时想到将同学发过来的文档转换为了一个模板（文件>新建>模板，然后把表格复制过来，保存为“值班日志表.dot”即可），这样一个一模一样的表格就有了，接下来就是用程序插入相应的内容了。当然了，程序中也必须做一些相应的修改：
1）在调用Documents集合的Add方法时，Template参数不再使用EmptyParam值，而是指定为“值班日志表.dot”，这样添加的文档将以“值班日志表.dot”为模板；
2）在插入相应的内容时，我使用的是一个比较笨的方法，但是对于这个不规则的表格来说却可能是最有效的方法：计算出该表格中共有多个个段落，然后通过语句在所有应插入内容的段落中插入内容。也懒得自己数了，定义了一个整型变量paraCount，将其赋值为WordDoc.Paragraphs.Count，最后用一个消息框显示出来，得到该表格有38个段落，最后注释掉以上代码：）
3）接下来的工作就是数数了，数到一个该插入内容的段落，就写一段代码插入相应的内容。比如：“值班时间”（表头）是第6段，接在后面该填入内容的空白段落就是第7段，于是写代码在第7段中插入实际内容。
最后，想说的是一个在操作Word 2000时很有用的帮助文件，VBAWRD9.CHM，里面详细介绍了Word 2000中使用的VBA，里面介绍了很多有用的对象、属性和方法，还有一些VB代码作为示例，很容易可以想到对应的Delphi代码。这个文件在Office 2000的安装盘里面可以找到，具体路径忘记了，烦请搜索：）
//单击“导出到Word文档”按钮事件处理程序
procedure TfrmDetails.btnExportClick(Sender: TObject);
var
V: Variant; //代表Word的变体类型变量
Template, NewTemplate, DocumentType, Visible: OleVariant; //Documents.Add()方法使用的参数
itemIndex: OleVariant;
fileName: Olevariant;
NoPrompt, OriginalFormat: OleVariant;
RouteDocument, SaveChanges: OleVariant;
//paraCount: Integer;
begin
//指定文档的路径和文件名
fileName := 'C:/LogAdmin/doc/' + '值班日志' + Trim(DBTextDate.Caption) + '.doc';
//如果该日志的对应Word文档已经存在则提示是否覆盖
if FileExists(fileName) = true then
begin
Beep;
if Application.MessageBox('文档已经存在，是否覆盖？','警告',MB_OKCANCEL)=IDCANCEL then
Abort;
end;
//测试当前是否运行了Word 2000
try
V := GetActiveOleObject('Word.Application');
except
//未运行则运行之
V := CreateOleObject('Word.Basic');
end;
try
//连接到Word 2000
WordApp.Connect;
except
Beep;
MessageDlg('不能生成文档，请确认是否安装了Word 2000！', mtError, [mbOK], 0);
Abort;
end;
//显示Word 2000
WordApp.Visible:=true;
//给调用Add函数使用的实参赋值
//Template := EmptyParam; //使用空白文档，即“Normal.dot”模板
Template := '值班日志表.dot'; //使用“值班日志表.dot”模板
NewTemplate := False;
DocumentType := wdNewBlankDocument;
Visible := true;
//调用Add函数添加一个文档
WordApp.Documents.Add(Template, NewTemplate, DocumentType, Visible);
//连接到新建的文档
itemIndex := 1;
WordDoc.ConnectTo(WordApp.Documents.Item(itemIndex));
//文档另存为
WordDoc.SaveAs(fileName);
//向Word文档中写入内容
//paraCount := WordDoc.Paragraphs.Count; //求得模板中的段落总数为38
//MessageDlg(IntToStr(paraCount), mtInformation, [mbOK], 0);
//在第3段中插入值班日期
WordDoc.Paragraphs.Item(3).Range.InsertAfter(DBTextDate.Caption);
//在第5段中插入值班人姓名
WordDoc.Paragraphs.Item(5).Range.InsertAfter(DBTextName.Caption);
//在第7段中插入值班时间
WordDoc.Paragraphs.Item(7).Range.InsertAfter(DBTextTime.Caption);
//在第10段中插入温度
WordDoc.Paragraphs.Item(10).Range.InsertAfter(DBTextT.Caption);
//在第12段中插入湿度
WordDoc.Paragraphs.Item(12).Range.InsertAfter(DBTextH.Caption);
//在第14段中插入天气
WordDoc.Paragraphs.Item(14).Range.InsertAfter(DBTextWeather.Caption);
//在第17段中插入工具
WordDoc.Paragraphs.Item(17).Range.InsertAfter(DBMemoTool.Text);
//在第19段中插入现场
WordDoc.Paragraphs.Item(19).Range.InsertAfter(DBMemoEnv.Text);
//在第21段中插入有无异常
WordDoc.Paragraphs.Item(21).Range.InsertAfter(lbException.Caption);
//在第26段中插入记录一
WordDoc.Paragraphs.Item(26).Range.InsertAfter(DBMemoR1.Text);
//在第29段中插入记录二
WordDoc.Paragraphs.Item(29).Range.InsertAfter(DBMemoR2.Text);
//在第33段中插入记录三
WordDoc.Paragraphs.Item(32).Range.InsertAfter(DBMemoR3.Text);
//在第36段中插入备注
WordDoc.Paragraphs.Item(36).Range.InsertAfter(DBMemoMemo.Text);

//保存文档
NoPrompt := false;
OriginalFormat := wdOriginalDocumentFormat;
WordApp.Documents.Save(NoPrompt, OriginalFormat);

//关闭文档
SaveChanges := wdSaveChanges;
OriginalFormat := wdOriginalDocumentFormat;
RouteDocument := false;
WordApp.Documents.Close(SaveChanges, OriginalFormat, RouteDocument);
//断开和Word 2000的连接
WordApp.Disconnect;

MessageDlg('日志内容导出成功！保存为' + fileName, mtInformation, [mbOK], 0);
frmDetails.Close;
end;

终于在1个小时之前完成程序的更新，我也可以安心的考试和过节了，祝我自己圣诞节快乐先，也祝各位Delphi Fans圣诞快乐！




作者Blog：http://blog.csdn.net/neowang/

楼主，俺来领分啦～～
测试通过，Demo程序可到http://crazycock.ys168.com 下载。
－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
unit Unit1;

interface

uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
Dialogs, StdCtrls, WordXP, OleServer;

type
TForm1 = class(TForm)
Button1: TButton;
WordDocument1: TWordDocument;
WordApplication1: TWordApplication;
procedure Button1Click(Sender: TObject);
private
{ Private declarations }
public
{ Public declarations }
end;

var
Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
DocFile:OleVariant;
CurPara:OleVariant;
CurPageCout:Integer;
begin
WordApplication1.Connect;
WordApplication1.Visible:=True; //如果为False则看不见Word，但是别忘了用完就关掉
DocFile:=ExtractFilePath(ParamStr(0))+'记事本.doc';
//打开doc
WordDocument1.ConnectTo(WordApplication1.Documents.Open(DocFile,EmptyParam,EmptyParam,EmptyParam,EmptyParam,
EmptyParam,EmptyParam,EmptyParam,EmptyParam,EmptyParam,EmptyParam,
EmptyParam,EmptyParam,EmptyParam,EmptyParam));

//关闭拼音查找和语法查找，以便提高程序运行的效率
WordApplication1.Options.CheckSpellingAsYouType := False;
WordApplication1.Options.CheckGrammarAsYouType := False;

// ShowMessage('目前有'+IntToStr(WordDocument1.Paragraphs.Count)+'段。');
// ShowMessage('目前有'+IntToStr(WordDocument1.Sections.Count)+'节。');
// ShowMessage('目前有'+IntToStr(WordDocument1.Sentences.Count)+'句。');
// ShowMessage('目前有'+IntToStr(WordApplication1.Selection.Information[wdNumberOfPagesInDocument])+'页');

//先插入两行再说，这两行是你需要的两行置底的文字
WordDocument1.Paragraphs.Add(EmptyParam);
CurPara:=WordDocument1.Paragraphs.Count;
WordDocument1.Paragraphs.Item(CurPara).Range.Font.Color:=wdColorRed;
WordDocument1.Paragraphs.Item(CurPara).Range.Font.Size:=20;
WordDocument1.Paragraphs.Item(CurPara).Range.Text:='末尾一行！！！';
//
WordDocument1.Paragraphs.Add(EmptyParam);
CurPara:=WordDocument1.Paragraphs.Count;
WordDocument1.Paragraphs.Item(CurPara).Range.Font.Color:=wdColorGreen;
WordDocument1.Paragraphs.Item(CurPara).Range.Font.Size:=10;
WordDocument1.Paragraphs.Item(CurPara).Range.Text:='末尾二行！！！';
//开始添加空行，直到页数发生变化
CurPageCout:=WordApplication1.Selection.Information[wdNumberOfPagesInDocument];
repeat
CurPara:=WordDocument1.Paragraphs.Count-1;//加了末尾两行后有几段文字，减去1得到"末尾一行"的位置
CurPara:=WordDocument1.Paragraphs.Item(CurPara).Range;
WordDocument1.Paragraphs.Add(CurPara);
until WordApplication1.Selection.Information[wdNumberOfPagesInDocument]>CurPageCout;
WordDocument1.Undo;//上面的做法，其实已经跑多了一行，当然要Undo一下。
ShowMessage('搞定！');
//保存、退出
//.........
end;

end.

那个Demo下载的位置在“测试”文件夹中，叫做“总在页末尾插入两行.rar”

我综合了两位大虾的程序,实现了在WORD中输入不需要改变的文字建立模板,然后在要在程序中修改的地方插入书签,最后用以下程序复制模板并在相应的地方进行修改:
procedure TgcReport2.SpeedButton2Click(Sender: TObject);
//uses Word2000, ComObj;
//WordApp: TWordApplication;
//WordDoc: TWordDocument;
var
V:Variant;
Template,NewTemplate,DocumentType,Visible:OleVariant;
itemIndex:OleVariant;
Doc_Handle: OleVariant;
fileName,oldfilename:Olevariant;
BookMark_Name: string;
NoPrompt,OriginalFormat:OleVariant;
begin
fileName:='e:/nanhua/document/'+Trim(edit1.text)+'.doc';
oldfilename:='E:/nanhua/document/1.doc';
//如果该日志的对应Word文档已经存在则提示是否覆盖
if FileExists(fileName)=true then
begin
Beep;
if Application.MessageBox('文档已经存在，是否覆盖？','警告',MB_OKCANCEL)=IDCANCEL then
Abort;
end;
//测试当前是否运行了Word 2000
try
V:=GetActiveOleObject('Word.Application');
except
//未运行则运行之
V:=CreateOleObject('Word.Basic');
end;
try
//连接到Word 2000
WordApp.Connect;
except
Beep;
MessageDlg('不能生成文档，请确认是否安装了Word 2000！',mtError,[mbOK],0);
Abort;
end;
//显示Word 2000
WordApp.Visible:=true;
//给调用Add函数使用的实参赋值
Template:=EmptyParam;
NewTemplate:=False;
DocumentType:=wdNewBlankDocument;
Visible:=true;
//调用Add函数
Doc_Handle:= WordApp.Documents.add(oldfilename,NewTemplate,DocumentType,Visible);
//连接到新建的文档
itemIndex:=1;
WordDoc.ConnectTo(WordApp.Documents.Item(itemIndex));
//文档另存为
WordDoc.SaveAs(fileName);
try
BookMark_Name := 'book1';
Doc_Handle.Application.Selection.goto(What := wdGoToBookmark, Name := BookMark_Name);
Doc_Handle.Application.Selection.Text := '这个是替换book1的结果';

BookMark_Name := 'book2';
Doc_Handle.Application.Selection.goto(What := wdGoToBookmark, Name := BookMark_Name);
Doc_Handle.Application.Selection.Text := '这个是替换book2的结果';
except
end;
//保存文档
NoPrompt:=false;
OriginalFormat:=wdOriginalDocumentFormat;
WordApp.Documents.Save(NoPrompt,OriginalFormat);
//关闭文档
//SaveChanges:=wdSaveChanges;
//OriginalFormat:=wdOriginalDocumentFormat;
//RouteDocument:=false;
//WordApp.Documents.Close(SaveChanges,OriginalFormat,RouteDocument);
//断开和Word 2000的连接
WordApp.Disconnect;

MessageDlg('内容导出成功！保存为'+fileName,mtInformation,[mbOK],0);
end;

呵呵～8错8错～～楼主用delphi做办公自动化的啊？