哪位大哥行行好，给个串口收发的源码给我看看好不好 ( 积分: 100 )

调用WIN API同卡串口收发，我用
if not WriteFile(hcom, Str[1], ByteToWrite, BytesWritten, nil) then
ret := GetLastError;
ret返回87是怎么回事？？？

谢谢各位大哥了

调用WIN API同卡串口收发，我用
if not WriteFile(hcom, Str[1], ByteToWrite, BytesWritten, nil) then
ret := GetLastError;
ret返回87是怎么回事？？？

谢谢各位大哥了

http://www.delphibbs.com/delphibbs/dispq.asp?lid=3043115

我用的是MSComm，而且学习时间不长，总的来说串口数据收发不难，关键是变量类型要匹配，还有标准数据线要2，3口对接，这样才能收发数据。

我要的是API函数操作串口的例子，哪位大哥给一份给我啊

给个邮箱，我给你一个完整的串行口控件的源码
My Mail: treemanwww@163.com

{*******************************************************}
{ }
{ Newpower Software LIR-256B01 }
{ 串口API定义单元 }
{ }
{ Copyright (c) 2004, Newpower Corporation }
{ Date: 2004-4-10 }
{ Check: 2004-4-21, 2004-7-2 }
{ Author: muhx }
{ }
{*******************************************************}

unit COMDefineUnit;

interface

uses Windows, SysUtils;

type
TComPort = Class
private
FTimeOut: COMMTIMEOUTS;
FiOutQueue: Integer;
FiInQueue: Integer;
FiEventMask: Integer;
public
function CheckConnect: Boolean;
function Connect: Boolean;
function ChangeComSet(nBaud,nParity: Integer): Boolean;
function ReadData(p: PChar; Length: Integer): Boolean;
function WriteData(p: PChar; Length: Integer): Boolean;
function Close: Boolean;
procedure ClearComPort;
procedure SetComPara(iParity,iStopBits,iByteSize,iBaudRate: Integer);
public
constructor Create(strCom: string);
destructor Destroy; override;
private
FsCom: string;
FiParity: Integer;
FiBaud: Integer;
FiStopBits: Integer;
FiByteSize: Integer;
FhSerial: THANDLE;
end;
{ TComPort }

implementation


constructor TComPort.Create(strCom: string);
begin
FhSerial := INVALID_HANDLE_VALUE;

FiInQueue := 4096;
FiOutQueue := 4096; //quene buffer length
FiEventMask := EV_RXCHAR; //Every char

FTimeOut.ReadIntervalTimeout := 50; //the inter time of the two following read char
FTimeOut.ReadTotalTimeoutMultiplier := 5; //
FTimeOut.ReadTotalTimeoutConstant := 100; //当没有字节时立刻返回
FTimeOut.WriteTotalTimeoutMultiplier := 5; //每传输一个字节平均5ms;
FTimeOut.WriteTotalTimeoutConstant := 50; //5000//传输常量=50ms;

FsCom := UpperCase(strCom);
end;

//检查串口是否已经连接，若连接返回True,否则连接
function TComPort.CheckConnect: Boolean;
begin
if FhSerial <> INVALID_HANDLE_VALUE then
begin
Result := True;
Exit;
end;
Result := Connect;
end;

//打开串口
function TComPort.Connect: Boolean;
var
d: DCB;
begin
if FhSerial <> INVALID_HANDLE_VALUE then
CloseHandle(FhSerial);

FhSerial := CreateFile(PChar(FsCom), GENERIC_READ or GENERIC_WRITE,
0, nil, OPEN_EXISTING,
FILE_FLAG_OVERLAPPED, // overlapped I/O
0);

if FhSerial = INVALID_HANDLE_VALUE then
begin
Result := False;
Exit;
end;

//ini comport
SetCommMask(FhSerial, FiEventMask);

SetCommTimeouts(FhSerial, FTimeOut);

SetupComm(FhSerial ,FiInQueue, FiOutQueue); //The size of buffer

d.DCBlength := sizeof(DCB);
GetCommState(FhSerial, d);
d.ByteSize := FiByteSize; // data size, xmit, and rcv
d.StopBits := FiStopBits; // one stop bit
d.BaudRate := FiBaud; // set the baud rate
d.Parity := FiParity; // no parity bit

if not SetCommState(FhSerial, d) then
begin
CloseHandle(FhSerial);
Result := False;
Exit;
end;

SetCommMask(FhSerial, EV_RXCHAR);
Result := True;
end;

//读取数据
function TComPort.ReadData(p: PChar; Length: Integer): Boolean;
var
o: TOverLapped;
lReadNum: DWORD;
begin
if FhSerial = INVALID_HANDLE_VALUE then
begin
Result := False;
Exit;
end;

lReadNum := 0;
Fillchar(o, Sizeof(o), 0);
o.hEvent := CreateEvent(nil, True, False, nil);//create an autoret Event object

if not ReadFile(FhSerial, p[0], Length, lReadNum, @o) then
begin
if GetLastError() = ERROR_IO_PENDING then
begin
if WaitForSingleObject(o.HEvent, INFINITE) = WAIT_OBJECT_0 then
begin
if not GetOverlappedResult(FhSerial, o, lReadNum, False) then
begin
Result := False;
Closehandle(o.HEVent);
Exit;
end;
end
else begin
Result := False;
Closehandle(o.HEVent);
Exit;
end;
end;
end;

CloseHandle(o.hEvent);
PurgeComm(FhSerial, PURGE_RXCLEAR or PURGE_TXCLEAR);//clear buffer
Result := True;
end;

//写入数据
function TComPort.WriteData(p: PChar; Length: Integer): Boolean;
var
o: TOverLapped;
lWriteNum: DWORD;
begin
if FhSerial = INVALID_HANDLE_VALUE then
begin
Result := False;
Exit;
end;

if Length < 0 then
begin
Result := True;
Exit;
end;

lWriteNum := 0;
FillChar(o, Sizeof(o), 0);
o.hEvent := CreateEvent(nil, True, False, nil);//create an autoret Event object

if not WriteFile(FhSerial, p[0], Length, lWriteNum, @o) then
begin
if GetLastError() = ERROR_IO_PENDING then
begin
if WaitForSingleObject(o.HEvent, INFINITE) = WAIT_OBJECT_0 then
begin
if not GetOverlappedResult(FhSerial, o, lWriteNum, False) then
begin
Result := False;
Closehandle(o.HEVent);
Exit;
end;
end
else begin
Result := False;
Closehandle(o.HEVent);
Exit;
end;
end;
end;

CloseHandle(o.hEvent);
PurgeComm(FhSerial, PURGE_RXCLEAR or PURGE_TXCLEAR);//clear buffer
Result := True;
end;

//改变串口状态
function TComPort.ChangeComSet(nBaud, nParity: Integer): Boolean;
var
d: DCB;
begin
if FhSerial = INVALID_HANDLE_VALUE then
begin
Result := False;
Exit;
end;

if not GetCommState(FhSerial, d) then
begin
Close;
Result := False;
Exit;
end;

FiParity := nParity;
FiBaud := nBaud;

d.BaudRate := FiBaud; // set the baud rate
d.ByteSize := 8; // data size, xmit, and rcv
d.Parity := FiParity; // no parity bit
d.StopBits := ONESTOPBIT; // one stop bit

if not SetCommState(FhSerial, d) then
begin
Close;
Result := False;
Exit;
end;

PurgeComm(FhSerial, PURGE_RXCLEAR or PURGE_TXCLEAR); //clear buffer
Result := True;
end;

//清空缓冲区数据
procedure TComPort.ClearComPort;
begin
PurgeComm(FhSerial, PURGE_RXCLEAR); //清除接受缓冲区中的所有数据
PurgeComm(FhSerial, PURGE_TXCLEAR); //清除传送缓冲区中的所有数据
end;

//设置DCB属性
procedure TComPort.SetComPara(iParity, iStopBits, iByteSize,
iBaudRate: Integer);
begin
FiParity := iParity;
FiBaud := iBaudRate;
FiStopBits := iStopBits;
FiByteSize := iByteSize;
end;

//关闭串口
function TComPort.Close: Boolean;
begin
if FhSerial <> INVALID_HANDLE_VALUE then
begin
CloseHandle(FhSerial);
FhSerial := INVALID_HANDLE_VALUE;
end;
Result:=True;
end;

//析构类
destructor TComPort.Destroy;
begin
if FhSerial <> INVALID_HANDLE_VALUE then
CloseHandle(FhSerial);
inherited;
end;

end.

仅供参考

谢谢几位大哥了