问题(100分)

用delphi，C也可编程控制。这个程序要有以下功能：
1，拨号连接。
2，读取管理对方数据库中所需文件数据。
3，断线。
***这涉及到语言对串口的控制，数据库的管理
关于数据库的读取和关于串口控制的问题我都很生。
如有建议者留QQ或Email不胜感激。
我看了一个月的Delphi3和串口技术，还是？？？
我的基础是基于DOS的C和Pascal，所以帮助我会很累
在是我的工作，做的了做不了都得做。
我做完了，我请大家喝anywhere

你需要多看书！比如网络数据库还有串口控制！因为你要做系统！
不是三言两语就明白的！[]

很多人都是用第三方控件，我是直接使用API，可以联系一下
muhx1981@126.com

多看些网络编程这方面的书！

给你一个我的模块吧，希望对你有用
仅供参考
{*******************************************************}
{ }
{ 串口API定义单元 }
{ }
{ Copyright (c) 2004 }
{ Date: 2004-4-10 }
{ Check: 2004-4-21 }
{ Author: muhx }
{ }
{*******************************************************}
unit COMDefineUnit;
interface
uses Windows,SysUtils;
type
TComPort = Class
private
m_TimeOut: COMMTIMEOUTS;
m_iOutQueue: Integer;
m_iInQueue: Integer;
m_iEventMask: Integer;
public
function CheckConnect: Boolean;
function Connect: Boolean;
function ChangeComSet(nBaud,nParity: Integer): Boolean;
function ReadData(p: PChar;
Length: Integer): Boolean;
function WriteData(p: PChar;
Length: Integer): Boolean;
function Close: Boolean;
procedure ClearComPort;
procedure SetComPara(iParity,iStopBits,iByteSize,iBaudRate: Integer);
public
constructor Create(strCom: string);
destructor Destroy;override;
private
m_sCom: string;
m_iParity: Integer;
m_iBaud: Integer;
m_iStopBits: Integer;
m_iByteSize: Integer;
m_hSerial: THANDLE;
end;
{ TComPort }
implementation

constructor TComPort.Create(strCom: string);
begin
m_hSerial := INVALID_HANDLE_VALUE;
m_iInQueue := 4096;
m_iOutQueue := 4096; //quene buffer length
m_iEventMask := EV_RXCHAR; //Every char
m_TimeOut.ReadIntervalTimeout := 50; //the inter time of the two following read char
m_TimeOut.ReadTotalTimeoutMultiplier := 5; //
m_TimeOut.ReadTotalTimeoutConstant := 100;
//当没有字节时立刻返回
m_TimeOut.WriteTotalTimeoutMultiplier := 5; //每传输一个字节平均5ms;
m_TimeOut.WriteTotalTimeoutConstant := 50; //5000//传输常量=50ms;
m_sCom := UpperCase(strCom);
end;

//检查串口是否已经连接，若连接返回True,否则连接
function TComPort.CheckConnect: Boolean;
begin
if m_hSerial <> INVALID_HANDLE_VALUE then
begin
Result := True;
Exit;
end;
Result := Connect;
end;

//打开串口
function TComPort.Connect: Boolean;
var
d: DCB;
begin
if m_hSerial <> INVALID_HANDLE_VALUE then
CloseHandle(m_hSerial);
m_hSerial := CreateFile(PChar(m_sCom),GENERIC_READ or GENERIC_WRITE,
0,nil,OPEN_EXISTING,
FILE_FLAG_OVERLAPPED, // overlapped I/O
0);
if m_hSerial = INVALID_HANDLE_VALUE then
begin
Result := False;
Exit;
end;

//ini comport
SetCommMask(m_hSerial,m_iEventMask);
SetCommTimeouts(m_hSerial,m_TimeOut);
SetupComm(m_hSerial,m_iInQueue,m_iOutQueue);
//The size of buffer
d.DCBlength := sizeof(DCB);
GetCommState(m_hSerial,d);
d.ByteSize := m_iByteSize; // data size, xmit, and rcv
d.StopBits := m_iStopBits; // one stop bit
d.BaudRate := m_iBaud; // set the baud rate
d.Parity := m_iParity; // no parity bit
if not SetCommState(m_hSerial,d) then
begin
CloseHandle(m_hSerial);
Result := False;
Exit;
end;

SetCommMask(m_hSerial,EV_RXCHAR);
Result := True;
end;

//读取数据
function TComPort.ReadData(p: PChar;
Length: Integer): Boolean;
var
o: TOverLapped;
lReadNum: DWORD;
begin
if m_hSerial = INVALID_HANDLE_VALUE then
begin
Result := False;
Exit;
end;

lReadNum := 0;
Fillchar(o,Sizeof(o),0);
o.hEvent := CreateEvent(nil,True,False,nil); //create an autoret Event object
if not ReadFile(m_hSerial,p[0],Length,lReadNum,@o) then
begin
if GetLastError() = ERROR_IO_PENDING then
begin
if WaitForSingleObject(o.HEvent,INFINITE) = WAIT_OBJECT_0 then
begin
if not GetOverlappedResult(m_hSerial,o,lReadNum,False) then
begin
Result := False;
Closehandle(o.HEVent);
Exit;
end;
end
else
begin
Result := False;
Closehandle(o.HEVent);
Exit;
end;
end;
end;

CloseHandle(o.hEvent);
PurgeComm(m_hSerial,PURGE_RXCLEAR or PURGE_TXCLEAR);//clear buffer
Result := True;
end;

//写入数据
function TComPort.WriteData(p: PChar;
Length: Integer): Boolean;
var
o: TOverLapped;
lWriteNum: DWORD;
begin
if m_hSerial = INVALID_HANDLE_VALUE then
begin
Result := False;
Exit;
end;

if Length < 0 then
begin
Result := True;
Exit;
end;

lWriteNum := 0;
FillChar(o,Sizeof(o),0);
o.hEvent := CreateEvent(nil,True,False,nil); //create an autoret Event object
if not WriteFile(m_hSerial,p[0],Length,lWriteNum,@o) then
begin
if GetLastError()=ERROR_IO_PENDING then
begin
if WaitForSingleObject(o.HEvent,INFINITE) = WAIT_OBJECT_0 then
begin
if not GetOverlappedResult(m_hSerial,o,lWriteNum,False) then
begin
Result := False;
Closehandle(o.HEVent);
Exit;
end;
end
else
begin
Result := False;
Closehandle(o.HEVent);
Exit;
end;
end;
end;

CloseHandle(o.hEvent);
PurgeComm(m_hSerial,PURGE_RXCLEAR or PURGE_TXCLEAR);//clear buffer
Result := True;
end;

//改变串口状态
function TComPort.ChangeComSet(nBaud, nParity: Integer): Boolean;
var
d: DCB;
begin
if m_hSerial = INVALID_HANDLE_VALUE then
begin
Result := False;
Exit;
end;

m_iParity := nParity;
m_iBaud := nBaud;
if not GetCommState(m_hSerial,d) then
begin
Close;
Result := False;
Exit;
end;

d.BaudRate := m_iBaud; // set the baud rate
d.ByteSize := 8; // data size, xmit, and rcv
d.Parity := m_iParity; // no parity bit
d.StopBits := ONESTOPBIT; // one stop bit
if not SetCommState(m_hSerial,d) then
begin
Close;
Result := False;
Exit;
end;

PurgeComm(m_hSerial,PURGE_RXCLEAR or PURGE_TXCLEAR); //clear buffer
Result := True;
end;

//清空缓冲区数据
procedure TComPort.ClearComPort;
begin
PurgeComm(m_hSerial,PURGE_RXCLEAR);
//清除接受缓冲区中的所有数据
PurgeComm(m_hSerial,PURGE_TXCLEAR);
//清除传送缓冲区中的所有数据
end;

//设置DCB属性
procedure TComPort.SetComPara(iParity, iStopBits, iByteSize,
iBaudRate: Integer);
begin
m_iParity := iParity;
m_iBaud := iBaudRate;
m_iStopBits := iStopBits;
m_iByteSize := iByteSize;
end;

//关闭串口
function TComPort.Close: Boolean;
begin
if m_hSerial <> INVALID_HANDLE_VALUE then
begin
CloseHandle(m_hSerial);
m_hSerial := INVALID_HANDLE_VALUE;
end;
Result:=True;
end;

//析构类
destructor TComPort.Destroy;
begin
if m_hSerial <> INVALID_HANDLE_VALUE then
CloseHandle(m_hSerial);
inherited;
end;

end.