修改Delphi的快捷键的问题(50分)

我想将Delphi的原用Ctrl+空格的快捷键修改为其他。可以实现吗？？（因为他同输入法有冲突）

有个叫cqDTCSmpKeyBind的bpl包，装上后会把ctrl+空格改成Alt+z.
到网上搜一下。
你用delphi哪个版本？我在网上找到for d6的，不过用16进制编辑器把里面的6都改成7，就可以在d7下安装了。

建议你跟宝兰的老总谈谈这个问题，呵呵~~~~~~~~~~~~~

Sorry，我在Google中没有搜索到该控件，可以发给我吗？

这个很容易啊，用OTA自己写一个包把code completion键绑定到其他键就可以了
网上很多这样的源代码

>>>>>>>>>>这个很容易啊，用OTA自己写一个包把code completion键绑定到其他键就可以了
>>>>>>>>>>网上很多这样的源代码
哪里有这方面的源代码？？？？请给个网址

unit uChangeCodeCompletion;

interface

procedure Register;

implementation

uses Windows, Classes, SysUtils,Menus, ToolsAPI, Controls ;

type
TBufferList = class(TNotifierObject, IUnknown, IOTANotifier,
IOTAKeyboardBinding)
function GetBindingType: TBindingType;
function GetDisplayName: string;
function GetName: string;
procedure BindKeyboard(const BindingServices: IOTAKeyBindingServices);
protected
procedure CodeCompletion(const Context: IOTAKeyContext; KeyCode: TShortcut;
var BindingResult: TKeyBindingResult);
end;

resourcestring
sBufferList = 'Szy''s Buffer List';

//register this key binding
procedure Register;
begin
(BorlandIDEServices as IOTAKeyBoardServices).AddKeyboardBinding(TBufferList.Create);
end;

{ TBufferList }


//the code to bind key
procedure TBufferList.BindKeyboard(const BindingServices: IOTAKeyBindingServices);
Begin
BindingServices.AddKeyBinding([ShortCut(VK_SPACE, [ssAlt])], CodeCompletion, Pointer(csCodeList or csManual));
end;

//do code completion
procedure TBufferList.CodeCompletion(const Context: IOTAKeyContext;
KeyCode: TShortcut; var BindingResult: TKeyBindingResult);
begin

(Context.EditBuffer.TopView as IOTAEditActions).CodeCompletion(Byte(Context.Context));
BindingResult := krHandled;

end;

function TBufferList.GetBindingType: TBindingType;
begin
Result := btPartial;
end;

function TBufferList.GetDisplayName: string;
begin
Result := sBufferList;
end;

function TBufferList.GetName: string;
begin
Result := 'Szy.BufferList';
end;

end.


把上面那个存成pas,然后兴建一个package,加入这个pas,然后install就可以了

多谢。。。非常感谢您。

接受答案了.