如何如何用delphi5提供的ado控件,连接数据库,并使用数据库;(50分)

如何如何用delphi5提供的ado控件,连接数据库,并使用数据库;
请说详细点,
听说用ado可脱离bde
谢谢

呵呵，delphi自己有一个例子，已经很详细了。

>>

下面是我编的程序,希望对你有帮助，后面再给你贴了一张别人的论文。

字段：编号为字符型
月份为整型。

procedure TForm1.RadioGroup1Click(Sender: TObject);
begin
if RadioGroup1.ItemIndex=0 then
begin
GroupBox1.Visible:=False;
with ADODataSetPack do begin
close;
CommandType:=cmdText;
CommandText:='Select * from Pack';
Open;
end;
end
else
begin
with ADODataSetPack do begin
close;
CommandType:=cmdText;
CommandText:='Select * from Pack where 月份=20';//为了不显示任何记录。
Open;
end;
GroupBox1.Visible:=True;
end;
end;

procedure TForm1.BitBtn1Click(Sender: TObject);
Var
SQLStr:string;
Sg:Integer;
begin
Sg:=0;
SQLStr:='Select * from pack';
if Trim(EditNo.Text)<>'' then
begin
Sg:=1;
SQLStr:=SQLStr+' where 编号 Like '+''''+Trim(EditNo.Text)+'''';
end;
if Trim(ComoBoxMouth.Text)<>'' then
begin
if Sg=1 then
SQLStr:=SQLStr+' and 月份='+ComoboxMouth.Text
else
SQLStr:=SQLStr+' Where 月份='+ComoboxMouth.Text;
end;
with ADODataSetPack do begin
close;
CommandType:=cmdText;
CommandText:=SQLStr;
Open;
end;
end;

ADO
在32位的Delphi中，可以声明一个variant变量（如AVariant），然后通过CreateOleObject创建一个OLE对象，如AVariant:=CreateOleObject ('ADODB.Connection')可以获得一个数据库连接对象的实例，然后就可以利用该对
象的方法和属性来操作ODBC数据库了。
下面简单介绍一下访问ODBC数据库所用到的ADO对象及其方法和属性。
1、数据库连接对象(ADODB. Connection)
该对象用于与ODBC数据库建立连接，所有对数据库的操作均通过该连接进行。
数据库连接对象ADODB. Connection的作用象Delphi中的TDatabase对象。
建立一个连接对象的方法为(AConnection为Variant类型变量)：
AConnection:=CreateOleObject(‘ADODB.Connection')
用于建立连接的方法为Open，使用语法为(以对象AConnection为例)：
AConnection.Open( ConnectionString, UserId, Password )
三个参数均为字符串类型，其中UserId和Password为用户名称和用户密码，用于访问
数据库使用时可以省略，因为在ConnectionString同样可以指定用户名称和用户密
码。ConnectionString是用来说明ODBC数据源信息的字符串，其格式为：
'Provider=ProviderName; DSN=DSNName; DRIVER=driver; SERVER=server; DATABASE=database; UID=user; PWD=password'
其中：
Provider：数据提供者，默认状态下为MSDASQL，为微软OLEDB，通常省略；
DSN：要打开的数据库对应的OBDC系统数据源(DSN)，是可选参数；
DRIVER：要打开的数据库所用的驱动程序名称，如Access对应Microsoft Access Driver (*.mdb)，是可选参数；
SERVER：要打开的数据库所在的服务器名称，本机可用(local)，是可选参数；
DATABASE：要打开的数据库名称，是可选参数；
UID：用户名称，用来访问数据库，是可选参数；
PWD：用户密码，用来访问数据库，是可选参数。
以上参数均为可选参数，但必须提供足够的信息来描述一个系统数据源。
假如已经定义了一个ODBC的系统DSN，名称为MyDsn，那么就可用以下语句建立一个数
据库连接：
AConnection.Open('DSN=MyDsn');
为了防止DSN不存在或其设置被他人修改时造成应用程序运行错误，可以用ADODB.Connection 创建一个临时ODBC数据源，这样可以保证我们使用的系统
DSN的参数设置是正确的。下面的语句可以创建一个临时ODBC系统DSN，对应一个ACCESS数据库，路径为C:/Inetpub/ wwwroot/ test.mdb：
AConnection.open('Driver= {Microsoft Access Driver (*.mdb)};DBQ=C:/inetpub /wwwroot/test.mdb')
建立一个ADODB.Connection后，如果不需要返回操作结果(如删除，修改，更新等操
作)就可以对数据库进行正常的SQL操作了，此时应用ADODB.Connection的另外一个
方法Execute，使用语法为：
AConnection.Execute( strSQL );
其中strSQL为执行操作的SQL语句，如删除操作可以为：delete from wfjcommu。用
AConnection.Close关闭一个数据库连接。
2、数据集对象(ADODB. RecordSet)
如果要执行查询操作并返回查询结果，或者要更方便地操作数据表，那就需要用到数
据集对象了。
数据集对象ADODB.RecordSet的作用象Delphi中的TTable或TQuery对象。
建立一个数据集对象的方法为(ARecordSet为Variant类型变量)：
ARecordSet:=CreateOleObject ('ADODB.RecordSet')
从数据表取得数据的方法为Open方法，具体使用方法为：
ARecordSet.Open( strCommand,ActiveConnection,int CursorType,intLockType, intCommandType );
其中：
strCommand：字符串，为命令参数，可以是一个Table名称，可以是一个SQL语句，也
可以是一个服务器上的存储过程(StoredProc)名称，具体需要后面的参数intCommandType来指定。
ActiveConnection：要使用的数据库连接，是一个ADODB. Connection对象。
intCursorType：长整数，数据集的Cursor类型，可选参数，请参见程序中注释。
intLockType：长整数，对数据表的加锁类型，可选参数，请参见程序中注释。
intCommandType：长整数，命令参数的类型，用来指明strCommand的作用，可以指
定strCommand为命令（如SQL语句）或数据表(TTable)或储存过程(StoredProc)，
可选参数，请参见程序中注释。
如执行一个SQL查询，可以采用如下语句：
ARecordSet.Open('Select * from wfjcommu',adOpenStatic,ad LockOptimistic,adCmdText);
其它常见属性和方法与TTable和TQuery相比较如下（具体请见ASP帮助文件）：
eof,bof: eof,bof．MoveFirst, MoveLast: First, LastMovePrevious, MoveNext: Prior, NextMove: MoveByAddNew: appendUpdate: PostClose: close
Delete加Update：delete，所有对数据表的修改均须用Update使操作有效，这与
Delphi不同。
Fields[FieldNo]: Fields[FieldNo]
Fields['FieldName']: FieldByName('FieldName')
3、其他常见对象(与Delphi对应的对象)：
ADODB.Field: TField ADODB.Parameter: TPara ADODB.Error: EDBEngineError
ADODB.Command：无 ADODB.Property：无
下面来看一个应用例子：
procedure TForm1.Button1Click(Sender: TObject);
{*****************************************************
用ADO操作ODBC数据库
本程序中，将创建一个临时的ODBC系统数据源，指向一个MsAccess数据库，然后对其
中的数据表进行显示、增加、修改、删除和查询操作
注意：请在Uses语句中包含ComObj单元
*****************************************************}
const{一些常量声明，详细请参见adovbs.inc}
{---- CommandType的常量说明 ----}
adCmdUnknown = 0008;//未知,需要系统来判断,速度慢,为缺省值
adCmdText = 0001;//命令语句如SQL语句
adCmdTable = 0002;//数据表名称
adCmdStoredProc = 0004;//存储过程名称

{---- CursorType的常量说明 ----}
adOpenForwardOnly = 0;//只能由前向后单向访问,为缺省值
adOpenKeyset = 1;//可见其他用户对数据的修改,但对其它用户的增加和删除不
可见
adOpenDynamic = 2;//其他用户对数据的增加修改和删除均可见
adOpenStatic = 3;//其他用户对数据的增加修改和删除均不可见

{---- LockType的常量说明 ---}
adLockReadOnly = 1;//只读,为缺省值
adLockPessimistic = 2;//在修改时,按单个记录锁定
adLockOptimistic = 3;//在修改后更新时,按单个记录锁定
adLockBatchOptimistic = 4;//在成批更新时记录锁定
var
AConnection, ARecordSet : variant;
longintTemp : integer;
strTemp : string;
intIndex : integer;
begin
{创建一个临时的ODBC数据源,指向一个MsAccess数据库,并利用此DSN建立一个
数据库连接}
AConnection := CreateOleObject('ADODB.Connection');
AConnection.Open('Driver={Microsoft Access Driver (*.mdb)};DBQ=C:
/inetpub/wwwroot/test');

{建立一个数据集对象,并从数据表中提取数据}
ARecordSet := CreateOleObject('ADODB.RecordSet');
ARecordSet.open( 'wfjcommu',AConnection,adOpenStatic,adLockOptimistic,adCmdTable );

memo1.lines.clear;
memo1.lines.add('********数据表原有的内容如下********');
{显示各个域的域名}
strTemp := '';
for intIndex := 0 to ARecordSet.Fields.count - 1 do
strTemp := strTemp + ARecordSet.Fields[intIndex].name+';';
memo1.lines.add( strTemp );

{显示各个域的内容}
while not ARecordSet.eof do
begin
strTemp := '';
for intIndex := 0 to ARecordSet.Fields.count - 1 do
strTemp := strTemp + ARecordSet.Fields[intIndex].value+';';
memo1.lines.add( strTemp );
ARecordSet.MoveNext;//移到下条，Next
end;

{增加一个记录}
ARecordSet.AddNew;//增加,Append
ARecordSet.Fields['AName'] := '1';//以FieldByName的方式存取
ARecordSet.Fields['Portable'] := '2';
ARecordSet.Fields(2) := '3';//以Fields[index]的方式存取
ARecordSet.Fields(3) := '4';
ARecordSet.Fields(4) := '5';
ARecordSet.Update;//更新，Post
ARecordSet.MoveFirst;//移到首条，First
memo1.lines.add('********增加了一条记录后的数据表的内容如下********');
{显示各个域的内容}
while not ARecordSet.eof do
begin
strTemp := '';
for intIndex := 0 to ARecordSet.Fields.count - 1 do
strTemp := strTemp + ARecordSet.Fields[intIndex].value+';';
memo1.lines.add( strTemp );
ARecordSet.MoveNext;//移到下条，Next
end;

{修改最后一条记录}
ARecordSet.MoveLast;
ARecordSet.Fields['AName'] := '11';//以FieldByName的方式存取
ARecordSet.Fields['Portable'] := '22';
ARecordSet.Fields(2) := '33';//以Fields[index]的方式存取
ARecordSet.Fields(3) := '44';
ARecordSet.Fields(4) := '55';
ARecordSet.Update;//更新，Post
ARecordSet.MoveFirst;//移到首条，First
memo1.lines.add('********修改了最后一条记录后的数据表的内容如下********');
{显示各个域的内容}
while not ARecordSet.eof do
begin
strTemp := '';
for intIndex := 0 to ARecordSet.Fields.count - 1 do
strTemp := strTemp + ARecordSet.Fields[intIndex].value+';';
memo1.lines.add( strTemp );
ARecordSet.MoveNext;//移到下条，Next
end;

{删除最后一条记录}
ARecordSet.MoveLast;//移到末条，Last
ARecordSet.delete;//删除，delete
ARecordSet.Update;//更新，在Delphi不需要
ARecordSet.MoveFirst;//移到首条，First
memo1.lines.add('********删除了最后一条记录后的数据表的内容如下********');
{显示各个域的内容}
while not ARecordSet.eof do
begin
strTemp := '';
for intIndex := 0 to ARecordSet.Fields.count - 1 do
strTemp := strTemp + ARecordSet.Fields[intIndex].value+';';
memo1.lines.add( strTemp );
ARecordSet.MoveNext;//移到下条，Next
end;

ARecordSet.Close;{关闭数据集}

{用SQL语句进行查询,查询姓名为“张三”的记录}
{注意，在SQL语句中，字符串应该用单引号包括起来}
ARecordSet.open( 'select * from wfjcommu where AName = ''张三''',
AConnection,adOpenStatic,adLockOptimistic,adCmdText );
memo1.lines.add('********张三的内容如下********');
memo1.lines.add( '共有' + IntToStr( ARecordSet.RecordCount ) + '条匹配的记录' );
{显示各个域的内容}
while not ARecordSet.eof do
begin
strTemp := '';
for intIndex := 0 to ARecordSet.Fields.count - 1 do
strTemp := strTemp + ARecordSet.Fields[intIndex].value+';';
memo1.lines.add( strTemp );
ARecordSet.MoveNext;//移到下条，Next
end;

{关闭数据集和数据库连接}
ARecordSet.close;
AConnection.close;
end;






还有一篇，也是转贴


可以找点控件,也可以:


本文向您揭示在Delphi中使用ADO是如何轻而易举，结合了ADO的Delphi应用程序，将不再依赖于BDE。
ADO的精髓在于利用简单的COM指令来快速方便的访问ODBC数据源，微软的表格、列表框等ActiveX控件使得用户可以简便的利用ADO工作；然而，本文中笔者仅仅向您展示了如何利用程序访问数据库，将不采用任何可视化数据控件。
本文将向您展示如何利用Variant或interfaces访问和修改ADO数据库，示例程序非常简单，可运行于Delphi 3或4。
安装和访问一个ADO数据库。
示例程序的代码不足150行，然而运行本程序必须首先安装ADO以及设置ODBC数据源。
ADO是一组COM组件的集合，允许程序员利用利用少量的简单代码访问数据库。
ADO通常和OLEDB、Universal Data Access以及Microsoft Data Access Components（MDAC）联系在一起。OLEDB产生较ADO为早，是后期各种技术的基础。
如果你已经安装了ADO，你会在你的计算机中发现ADODB.DLL或者是MSADO15.DLL，这些文件中包含了一个类库，其中包括了利用ADO编程所需的全部接口和常量。在Delphi中，选择菜单Project | Import Type Library，选择以上的DLL文件，然后确定，系统生成了一个基于ADODB.DLL的ADODB_TLB.Pas文件，这个文件中包含了所有Delphi ADO编程所需的声明。
最后一步的准备工作就是将Delphi演示数据库中的Clients.DBF设置为ODBC系统DSN，其别名为DBDemosDBase，驱动程序为Dbase 5。
以下程序清单同时利用Variants和Interfaces访问ADO：
unit Main;
{---------------------------------------------------------------------
Created Jan 5, 1999. Copyright (c) 1999 by Charlie Calvert
----------------------------------------------------------------------}
interface


uses Windows, Messages, SysUtils, Classes, Graphics, Controls,
Forms, Dialogs, StdCtrls, ComObj, Grids, ADODB_TLB, ExtCtrls;


const
SELECTSTRING = 'SELECT * FROM Clients.dbf';
DSNSTRING = 'DBDemosDBase';
type TForm1 = class(TForm)
StringGrid1: TStringGrid;
Panel1: TPanel;
VariantBtn: TButton;
InterfaceBtn: TButton;
UpdateBtn: TButton;
Edit1: TEdit;
procedure VariantBtnClick(Sender: TObject);
procedure InterfaceBtnClick(Sender: TObject);
procedure UpdateBtnClick(Sender: TObject);
procedure StringGrid1SelectCell(Sender: TObject; ACol, ARow: Integer;
var CanSelect: Boolean);

private
procedure Display(RecordSet: _RecordSet); { Private declarations }
public { Public declarations }
end;
var Form1: TForm1;implementation
uses
ActiveX;
{$R *.DFM}
procedure TForm1.Display(RecordSet: _RecordSet);
var
Y, i: Integer;
begin
Y := 1;
repeat
for i := 0 to 6 do
StringGrid1.Cells[i, Y] := RecordSet.Fields.Value;
RecordSet.Move(1, EmptyParam);
Inc(Y);
until RecordSet.EOF;
end;
procedure TForm1.InterfaceBtnClick(Sender: TObject);
var RecordSet: _RecordSet;
DSN: string;
begin
// 生成空的recordset object
OleCheck(CoCreateInstance(CLASS_RecordSet, nil,
CLSCTX_ALL, IID__RecordSet, RecordSet));
DSN := 'dsn=' + DSNSTRING;
// 填写数据
RecordSet.Open(SelectString, DSN, adOpenForwardOnly,
adLockReadOnly, adCmdUnspecified);
// 显示数据
Display(RecordSet);
UpdateBtn.Enabled := True;
end;
procedure TForm1.UpdateBtnClick(Sender: TObject);
var RecordSet: _RecordSet;
DSN: string;
begin
OleCheck(CoCreateInstance(CLASS_RecordSet, nil,
CLSCTX_ALL, IID__RecordSet, RecordSet));
DSN := 'dsn=' + DSNSTRING;
// Fill the recordset
RecordSet.Open(SELECTSTRING, DSN, adOpenDynamic,
adLockOptimistic, adCmdUnspecified);
// 修改
RecordSet.Move(StringGrid1.Row - 1, EmptyParam);
RecordSet.Fields[StringGrid1.Col].Value := Edit1.Text;
RecordSet.Update(EmptyParam, EmptyParam);
RecordSet.MoveFirst;
Display(RecordSet);
end;
procedure TForm1.VariantBtnClick(Sender: TObject);
var
RecordSet: OleVariant;
Y, i: Integer;
begin
// Create an empty recordset object
RecordSet := CreateOleObject('ADODB.Recordset');
// Fill the recordset
RecordSet.Open(SELECTSTRING, DSNSTRING);
// Display the data
Y := 1;
repeat
for i := 0 to 6 do
StringGrid1.Cells[i, Y] := RecordSet.Fields.Value;
RecordSet.Move(1);
Inc(Y);
until RecordSet.EOF;
end;
procedure TForm1.StringGrid1SelectCell(Sender: TObject; ACol,
ARow: Integer; var CanSelect: Boolean);
begin
Edit1.Text := StringGrid1.Cells[ACOl, ARow];
end;
end.
这个程序有三个按钮，一个StringGrid以及一个编辑框，第一个按钮利用以Variants连接的ADO填充表格，第二个则利用Inteface进行连接。
第三个按钮用于修改数据，当用户单击StringGrid的单元格时，单元格中的数据会显示于编辑框中，可以修改编辑框中的数据，然后单击这个按钮，将会修改这个单元格以及数据库中的数据。
ADO中含有许多不同的对象，本文将集中讲述RecordSet和Fields这两个对象。
可以用如下的代码生成一个RecordSet的实例：
var
RecordSet: OleVariant;
begin
RecordSet := CreateOleObject('ADODB.Recordset');
... // Code omitted here
end;
CreateOleObject声明于ComObj.Pas中。它是ActiveX.Pas中的核心函数CoCreateInstance的一个简单包装。
要打开数据库，可利用以下代码：
const
SELECTSTRING = 'SELECT * FROM Clients.dbf';
DSNSTRING = 'DBDemosDBase';

begin
RecordSet := CreateOleObject('ADODB.Recordset');
RecordSet.Open(SELECTSTRING, DSNSTRING);
.. // Code omitted here
end;
Open方法有很多参数，但是在这个程序中我们只处理其中的两个。第一个是我们要执行的SQL语句，第二个是我们要操作的数据库。
当打开一个数据集时，数据集游标位于第一个记录，可以用下面的代码访问这个记录：

MyString := RecordSet.Fields[0].Value;
MyString := RecordSet.Fields[1].Value;

要移动游标，可以用RecordSet对象的Move方法：
RecordSet.Move(1);


利用Interface访问ADO：

利用Interface访问ADO的步骤同从前的例子大致相同：

procedure TForm1.InterfaceBtnClick(Sender: TObject);
var RecordSet: _RecordSet;
DSN: string;
begin
// Create an empty recordset object
OleCheck(CoCreateInstance(CLASS_RecordSet, nil,
CLSCTX_ALL, IID__RecordSet, RecordSet));
DSN := 'dsn=' + DSNSTRING;
// Fill the recordset
RecordSet.Open(SelectString, DSN, adOpenForwardOnly,
adLockReadOnly, adCmdUnspecified);
// Display the data
Display(RecordSet);
UpdateBtn.Enabled := True;
end;

同前一节的代码不同，这些代码必须包含ADODB_TLB.PAS。
这一段代码用ADODB_TLB.PAS中声明的_RecordSet代替了Variants。
这里直接调用了CoCreateInstance来生成对象的实例。第一个参数传递了声明于ADODB_TLB.PAS中的常量CLASS_RecordSet，它代表RecordSet的Class ID，第四个参数为IID__RecordSet，也是声明于ADODB_TLB.PAS中的，注意，它带有两条下划线！最后一个参数是我希望建立的实例。
当调用recordSet.Open的时候，应该穿第五个参数。
const
SELECTSTRING = 'SELECT * FROM Clients.dbf';
DSNSTRING = 'DBDemosDBase';

begin
.. // Code omitted
DSN := 'dsn=' + DSNSTRING;
RecordSet.Open(SelectString, DSN, adOpenForwardOnly,
adLockReadOnly, adCmdUnspecified);
.. // Code omitted
end;
在前一节的例子中，可以只传递两个参数，这是因为Variants允许忽略参数，这时采用缺省值。当采用Interfaces时，则必须明确的定义参数。如果希望采用缺省值，则可以向下面这样调用函数：
RecordSet.Open(SelectString, DSN, EmptyParam, EmptyParam, EmptyParam);
在这里我们使用了EmptyParam这样一个Variant，它被声明于System.Pas，这些参数将采用缺省值。上面的例子中我用了声明于ADODB_TLB.PAS中的真正的缺省值。此类问题可参考Data Access SDK中的相关文件。
打开数据集以后，就可以用同上一节相同的方法显示数据。唯一的不同就是RecordSet.Move方法要有两个参数。
procedure TForm1.Display(RecordSet: _RecordSet);
var Y, i: Integer;
begin
Y := 1;
Repeat
for i := 0 to 6 do
StringGrid1.Cells[i, Y] := RecordSet.Fields.Value;
RecordSet.Move(1, EmptyParam);
Inc(Y);
until RecordSet.EOF;
end;

修改数据
当修改数据时，不能用打开数据集时使用的缺省值，而是应该传递以下的参数：
const
adOpenDynamic = $00000002;
adLockOptimistic = $00000003;
adCmdUnspecified = $FFFFFFFF;
begin
.. // Call CoCreateInstance
DSN := 'dsn=' + DSNSTRING;
RecordSet.Open(SELECTSTRING, DSN, adOpenDynamic, adLockOptimistic,
adCmdUnspecified);
.. // Code ommitted here
end;

无论你用的是Variants还是Interfaces，这段代码都将正常工作。
当你的数据集以可读写的方式打开时，如adLockOptimistic方式，就可以修改数据库的内容了：
RecordSet.Fields[0].Value := Edit1.Text;
RecordSet.Update(EmptyParam, EmptyParam);
这段代码可以修改当前记录的内容。当然也可以利用字段数组以及Move方法修改任何记录。如果用的是Variants方式，可以不传递任何参数。
在例子中，我采用了一种简单的方法来编辑表中的字段。如果用户在某一个字段商单击，其数值会显示于编辑框中：
procedure TForm1.StringGrid1SelectCell(Sender: TObject; ACol,
ARow: Integer; var CanSelect: Boolean);
begin
Edit1.Text := StringGrid1.Cells[ACOl, ARow];
end;

用于更新数据的代码如下：
RecordSet.Move(StringGrid1.Row - 1, EmptyParam);
RecordSet.Fields[StringGrid1.Col].Value := Edit1.Text;
RecordSet.Update(EmptyParam, EmptyParam);

第一行将数据集游标移动到表格当前行，第二行修改数据，第三行提交修改。
最后一步将把数据集游标移动到第一条记录，然后调用相同的过程显示修改后的数据库。
RecordSet.MoveFirst;
Display(RecordSet);

接受答案了.