********** 一个超难问题，高手们请进。 **********(100分)

[red]我想记录下用户（电脑操作者）在电脑里的一系统操作。完后，再由程序依照用户的操作再操作一次。[/red]

如（XP下）：
[purple]用户单击[开始]按钮打开开始菜单，
再单击[所有程序]打开程序列表菜单，
再单击[附件]，再单击[记事本]，于是记事本打开，
鼠标滑进记事本，单击记录本，再输入一串字符，
再单击［文件］菜单打开，再单击［保存］，出来保存对话框．
对话框中，单击＂保存在＂下拉框，选择一个保存目录．
再单击＂文件名＂输入框，输入文件名．
再单击＂保存＂按钮保存文件．[/purple]

[blue]整个过程记录下来，再由程序在没有用户干预（电脑操作者吃饭去了）的情况下，程序再把上面的过程执行一遍．[/blue]


[green]这个问题怎么实现？？？？？？？？？？？[/green]

呵呵，用钩子可以实现你的操作重放。
不过我还搞不来那么高深的，你可以看看delphibbs的以前的记录或者看超级猛料
里面会给你解释的比较清楚的。

这不是“宏”吗？？

这样的软件多得很了.

我推荐一款软件----按键精灵.玩网络游戏挂机时用的,可以自己编辑里面的宏,很简单的,你去一些网站搜索一下,找不到的话来找我要,自己编辑一些宏就可以搞定了.

你的目的无非是要不停的生成一些文本文档,要这么麻烦吗?就算要这样做,也不需要从开始菜单开始啊,你可以先打开一个[记事本],然后再完成你后面说得这些功能,就是不停的在记事本里面输入一些东西,然后保存就是了.

hook
也可以将操作过程的界面保存（图片）起来，然后需要时顺序显示图

　　在Windows大行其道的今天，windows界面程序受到广大用户的欢迎。对这些程序的操作不外乎两种，键盘输入控制和鼠标输入控制。有时，对于繁杂的，或重复性的操作，我们能否通过编制程序来代替手工输入，而用程序来模拟键盘及鼠标的输入呢？答案是肯定的。这主要是通过两个API函数来实现的。 　　

　　下面以Delphi为例来介绍一下如何实现这两个功能。模拟键盘我们用Keybd_event这个api函数，模拟鼠标按键用mouse_event函数。大家不用担心，在delphi里调用api函数是很方便的事。 　　

　　先介绍一下Keybd_event函数。Keybd_event能触发一个按键事件，也就是说回产生一个WM_KEYDOWN或WM_KEYUP消息。当然也可以用产生这两个消息来模拟按键，但是没有直接用这个函数方便。Keybd_event共有四个参数，第一个为按键的虚拟键值，如回车键为vk_return,　tab键为vk_tab。第二个参数为扫描码，一般不用设置，用0代替就行。第三个参数为选项标志，如果为keydown则置0即可，如果为keyup则设成“KEYEVENTF_KEYUP”，第四个参数一般也是置0即可。用如下代码即可实现模拟按下i键，其中的$49表示i键的虚拟键值：



keybd_event($49,0,0,0);
keybd_event($49,0,KEYEVENTF_KEYUP,0); ... 　　

　　

　　mouse_event最好配合setcursorpos(x,y)函数一起使用，与Keybd_event类似，mouse_event有五个参数，第一个为选项标志，为MOUSEEVENTF_LEFTDOWN时表示左键按下，为MOUSEEVENTF_LEFTUP表示左键松开，向系统发送相应消息。第二三个参数分别表示x,y相对位置，一般可设为0,0,第四五个参数并不重要，一般也可设为0,0。若要得到Keybd_event和mouse_event函数的更详细的用法，可以查阅msdn或delphi帮助。下面是关于mouse_event的示例代码：
　

setcursorpos(20,132);
mouse_event(MOUSEEVENTF_LEFTDOWN,0,0,0,0);
mouse_event(MOUSEEVENTF_LEFTUP,0,0,0,0);
mouse_event(MOUSEEVENTF_LEFTDOWN,0,0,0,0);
mouse_event(MOUSEEVENTF_LEFTUP,0,0,0,0); ...


　　　上面的代码表示鼠标的双击，若要表示单击，用两个mouse_event即可(一次放下，一次松开)。 　
　　　注意，不管是模拟键盘还是鼠标事件，都要注意还原，即按完键要松开，一个keydown对应一个keyup；鼠标单击　完也要松开， 不然可能影响程序的功能。 　
　
　　　好了，希望本文能让你对模拟键盘和鼠标按键有个初步的了解，如果想更深入的了解其中的奥妙，可以查阅详实的msdn在线帮助，并多多动手实践。如果对程序有不明白的地方，可以到coolsofts.yesky.net下载相应的源程序

up

用HOOK很容易实现的。

通过Delphi建立键盘鼠标动作纪录与回放

www.applevb.com
很多的教学软件或系统监视软件可以自动记录回放用户的输入文字或点击按钮等操作操作，这个功能的实现是使用
了Windows的Hook函数。
Windows提供API函数SetwindowsHookEx来建立一个Hook，通过这个函数可以将一个程序添加到Hook链中监视Windows
消息，函数语法为：
SetWindowsHookEx(idHook: Integer; lpfn: TFNHookProc; hmod: HINST; dwThreadId: DWORD)
其中参数idHook指定建立的监视函数类型。通过Windows MSDN帮助可以看到，SetwindowsHookEx函数提供15种不同
的消息监视类型，在这里我们将使用WH_JOURNALRECORD和WH_JOURNALPLAYBACK来监视键盘和鼠标操作。参数lpfn指定消
息函数，在相应的消息产生后，系统会调用该函数并将消息值传递给该函数供处理。函数的一般形式为：
Hookproc (code: Integer; wparam: WPARAM; lparam: LPARAM): LRESULT stdcall;
其中code为系统指示标记，wParam和lParam为附加参数，根据不同的消息监视类型而不同。只要在程序中建立这样
一个函数再通过SetwindowsHookEx函数将它加入到消息监视链中就可以处理消息了。
在不需要监视系统消息时需要调用提供UnHookWindowsHookEx来解除对消息的监视。
WH_JOURNALRECORD和WH_JOURNALPLAYBACK类型是两种相反的Hook类型，前者获得鼠标、键盘动作消息，后者回放鼠
标键盘消息。所以在程序中我们需要建立两个消息函数，一个用于纪录鼠标键盘操作并保存到一个数组中，另一个用于
将保存的操作返给系统回放。
下面来建立程序，在Delphi中建立一个工程，在Form1上添加3个按钮用于程序操作。另外再添加一个按钮控件和一
个Edit控件用于验证操作。
下面是Form1的全部代码

unit Unit1;

interface

uses
Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
StdCtrls;

type
TForm1 = class(TForm)
Button1: TButton;
Button2: TButton;
Button3: TButton;
Edit1: TEdit;
Button4: TButton;
procedure FormCreate(Sender: TObject);
procedure Button1Click(Sender: TObject);
procedure Button2Click(Sender: TObject);
procedure Button3Click(Sender: TObject);
private
{ Private declarations }
public
{ Public declarations }
end;

var
Form1: TForm1;

EventArr:array[0..1000]of EVENTMSG;
EventLog:Integer;
PlayLog:Integer;
hHook,hPlay:Integer;
recOK:Integer;
canPlay:Integer;
bDelay:Bool;
implementation

{$R *.DFM}
Function PlayProc(iCode:Integer;wParam:wParam;lParam:lParam):LRESULT;stdcall;
begin
canPlay:=1;
Result:=0;

if iCode < 0 then //必须将消息传递到消息链的下一个接受单元
Result := CallNextHookEx(hPlay,iCode,wParam,lParam)
else if iCode = HC_SYSMODALON then
canPlay:=0
else if iCode = HC_SYSMODALOFF then
canPlay:=1
else if ((canPlay =1 )and(iCode=HC_GETNEXT)) then begin
if bDelay then begin
bDelay:=False;
Result:=50;
end;
pEventMSG(lParam)^:=EventArr[PlayLog];
end
else if ((canPlay = 1)and(iCode = HC_SKIP))then begin
bDelay := True;
PlayLog:=PlayLog+1;
end;
if PlayLog>=EventLog then begin
UNHookWindowsHookEx(hPlay);
end;
end;

function HookProc(iCode:Integer;wParam:wParam;lParam:lParam):LRESULT;stdcall;
begin
recOK:=1;
Result:=0;

if iCode < 0 then
Result := CallNextHookEx(hHook,iCode,wParam,lParam)
else if iCode = HC_SYSMODALON then
recOK:=0
else if iCode = HC_SYSMODALOFF then
recOK:=1
else if ((recOK>0) and (iCode = HC_ACTION)) then begin
EventArr[EventLog]:=pEventMSG(lParam)^;
EventLog:=EventLog+1;

if EventLog>=1000 then begin
UnHookWindowsHookEx(hHook);
end;
end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
Button1.Caption:='纪录';
Button2.Caption:='停止';
Button3.Caption:='回放';
Button4.Caption:='范例';
Button2.Enabled:=False;
Button3.Enabled:=False;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
EventLog:=0;
//建立键盘鼠标操作消息纪录链
hHook:=SetwindowsHookEx(WH_JOURNALRECORD,HookProc,HInstance,0);
Button2.Enabled:=True;
Button1.Enabled:=False;
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
UnHookWindowsHookEx(hHook);
hHook:=0;

Button1.Enabled:=True;
Button2.Enabled:=False;
Button3.Enabled:=True;
end;

procedure TForm1.Button3Click(Sender: TObject);
begin
PlayLog:=0;
//建立键盘鼠标操作消息纪录回放链
hPlay:=SetwindowsHookEx(WH_JOURNALPLAYBACK,PlayProc,
HInstance,0);

Button3.Enabled:=False;
end;

end.

代码添加完毕后，运行程序，点击“纪录”按钮开始纪录操作，这时你可以在文本控件中输入一些文字或者点击
“范例”按钮，然后点击“停止”按钮停止纪录，再点击“回放”按钮就可以讲先前所做的操作回放。
在上面的程序中，HookProc是纪录操作的消息函数，每当有鼠标键盘消息发生时，系统都会调用该函数，消息信
息就保存在地址lParam中，我们可以讲消息保存在一个数组中。PlayProc是消息回放函数，当系统可以执行消息回放
时调用该函数，程序就将先前纪录的消息值返回到lParam指向的区域中，系统就会执行该消息，从而实现了消息回放。

有必要这么复杂吗？