给你一个完整的例子, 包括了线程处理的一般方法(自定义消息,通过消息传递数据):
当然,你也定义通过使用引用或指针来共享数据对象,引用是Delphi里的好东东
unit Unit1;
interface
uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
Dialogs, StdCtrls, ComCtrls;
const
// 自定义一个线程结束消息
WM_MYTHREAD_DONE = WM_USER + 1024;
type
TMyThread = Class(TThread)
private
// 窗口句柄
FOwnerHandle: HWND;
// 传入的进度条控件
FBar: TProgressBar;
// 进度
FPos: Integer;
// 初始化进度条
procedure InitStatus;
// 更新进度条
procedure UpdateStatus;
// 线程结束后向窗口发送消息
procedure FinalAct(Sender: TObject);
protected
procedure Execute;
override;
public
constructor Create(const OwnerHandle: HWND;
pBar: TProgressBar);
end;
TForm1 = class(TForm)
ProgressBar1: TProgressBar;
Button1: TButton;
Button2: TButton;
procedure Button1Click(Sender: TObject);
procedure Button2Click(Sender: TObject);
private
{ Private declarations }
TestThread: TMyThread;
// 接受线程终止发出的消息
procedure ThreadDone(var Msg: TMessage);
message WM_MYTHREAD_DONE;
public
{ Public declarations }
end;
var
Form1: TForm1;
implementation
{$R *.dfm}
{ TMyThread }
constructor TMyThread.Create(const OwnerHandle: HWND;
pBar: TProgressBar);
begin
FOwnerHandle := OwnerHandle;
FBar := pBar;
OnTerminate := FinalAct;
FreeOnTerminate := True;
inherited Create(False);
end;
procedure TMyThread.Execute;
begin
Synchronize(InitStatus);
// 初始化进度条
while (not Terminated) and (FPos < 100)do
begin
sleep(500);
// 这里放置你的业务代码....
Inc(FPos);
Synchronize(UpdateStatus);
// 更新进度条
end;
end;
procedure TMyThread.FinalAct(Sender: TObject);
begin
PostMessage(FOwnerHandle, WM_MYTHREAD_DONE, FPos, 0);
end;
procedure TMyThread.InitStatus;
begin
FBar.Max := 100;
FBar.Position := 0;
end;
procedure TMyThread.UpdateStatus;
begin
FBar.Position := FPos;
end;
procedure TForm1.Button1Click(Sender: TObject);
begin
TestThread := TMyThread.Create(Handle, ProgressBar1);
(Sender as TButton).Enabled := False;
Button2.Enabled := True;
end;
procedure TForm1.Button2Click(Sender: TObject);
begin
if Assigned(TestThread) then
TestThread.Terminate;
(Sender as TButton).Enabled := False;
end;
procedure TForm1.ThreadDone(var Msg: TMessage);
begin
Button1.Enabled := True;
ShowMessage(Format('线程终止,已经执行了%d次操作.', [Msg.WParam]));
end;
end.
